Excelマクロで作るキッチンタイマー

Excel上で動くキッチンタイマー（カウントダウンタイマー）のご紹介です。10分、1分、10秒のボタンが用意されていて、利用中はExcelの操作が可能です。加算時間を変更したり、時間がゼロになったときの音を変更するなどのカスタマイズができます。

動画版もあります

動画でも解説してます。テキストよりそっちのほうが好きという方はこちらからどうぞ！

ダウンロード

こちらからzipファイルをダウンロードして、展開してください。

以下の2つのファイルが入っています。

• F_Timer.frm
• F_Timer.frx

インポート

VBEのプロジェクトエクスプローラー内の「VBAProject」を右クリックして「ファイルのインポート」を選択し、「F_Timer.frm」を読み込みます。

プロジェクトエクスプローラーがこのようになっていれば、正しく読み込まれています。

標準モジュールをへコードを書く

ツールバーの「挿入」→「標準モジュール」をクリックします。

挿入した標準モジュールに以下をコピペします。

Sub showTimer()
  F_Timer.Show vbModeless
End Sub

起動

Excel画面で「開発」→「マクロ」または「Alt+F8」キーでマクロウィンドウを表示し、「showTimer」プロシージャを選択して実行します。

タイマーが起動するので、お好きな時間を設定して「スタート/ストップ」して使います。起動中もExcelの操作は可能です。

カスタマイズ

加算時間を変更する

時間を加算するボタンを、好きな間隔に変更することができます。VBEで「F_Timer」をダブルクリックして、好きなボタンのCaptionを変更します。例として「btn_1」を「5分」で解説します。

コード画面で、対象の「Private Sub ボタン名_Click()」のハイライト部分を以下のように書き換えます。5行目のDateAddは、日付や時間を計算する関数です。1分ならDateAdd("n", 1, 対象)、1秒ならDateAdd("s", 1, 対象)のように指定します。

Private Sub btn_1_Click()
  '## ボタン1(5分)クリック時
  
  Dim cnt As Date '計算用変数
  cnt = DateAdd("n", 5, "00:" & Me.txb_display.Value) '加算
  Me.txb_display.Value = Format(cnt, "nn:ss") 'テキストボックスの表示を更新
  inProgress = False '実行中フラグをオフ
  Me.txb_hidden.SetFocus '隠しテキストボックスへフォーカスを移す
End Sub

終了時の音を変更する

デフォルトでは、OSのブザー音が鳴ります。「F_Timer」モジュールの「btn_startstop_Click」プロシージャの、以下の33行目をコメントアウトして34行目のコメントアウトを外すと、WindowsMediaPlayerを起動して任意ファイルの再生へ変更することができます。

34行目前半のC:\Program Files\Windows Media Player\wmplayer.exeはMediaPlayerの起動部分です。たいていの場合はこのまま動くと思いますが、メディアプレイヤーの場所を変更している場合は、その場所を指定してください。

34行目後半のC:\Sample\00.wavが、再生するファイルを指定する部分です。ここを任意のものに変更してください。

Private Sub btn_startstop_Click()
  '## スタート/ストップボタンクリック時
  
  '残り時間がゼロだったら中止
  If Me.txb_display.Value = "00:00" Then Exit Sub
  
  Dim endTime As Date '終了時刻用変数
  If inProgress Then
    '実行中フラグがオンの場合
    inProgress = False '実行中フラグをオフ
  Else
    '実行中フラグがオフの場合
    endTime = DateAdd("n", Left(Me.txb_display.Value, 2), Time) '現在時刻+指定秒
    endTime = DateAdd("s", Right(Me.txb_display.Value, 2), endTime) '現在時刻+指定分
    inProgress = True '実行中フラグをオン
  End If
  
  '隠しテキストボックスへフォーカスを移す（ボタン押し込み状態解除のため）
  Me.txb_hidden.SetFocus

  Dim cnt As Double '計算用変数
  Do Until Not inProgress Or Me.txb_display.Value = "00:00" '実行中フラグがオフまたは残り時間がゼロまで繰り返す
    'テキストボックスの表示を更新
    cnt = DateDiff("s", Time, endTime) '終了時刻-現在時刻
    Me.txb_display.Value = Format(TimeSerial(0, 0, cnt), "nn:ss") '分：秒 で表示
    
    'イベントを実行
    DoEvents
  Loop
  
  '実行中フラグがオンかつ残り時間がゼロだったら音を鳴らす
  If inProgress And Me.txb_display.Value = "00:00" Then
    'Beep 'ブザーを鳴らす
    Shell "C:\Program Files\Windows Media Player\wmplayer.exe C:\Sample\00.wav", vbNormalFocus 'メディアプレイヤーを起動
  End If
  
  inProgress = False '実行中フラグをオフ
End Sub

以上です！

動画のラストでもしゃべっていますが、純粋なタイマー機能としては、スマートフォンなどを使ったほうが使い勝手は良いです。ただ、コードを見て、いじってみるという自作体験はまた面白いものがあるので、ちょっと遊んでみようかな、とか、なにかの参考になりそうだなと感じられたら、試してみてくださいね。